NixOSで最強のLinuxデスクトップを作ろう

                                          Package
                                            ┌┴┐
/nix/store/y0gvg44jdsbn8hnnr27ixjf102nk7a9x-git-2.41.0/
           └──────────────┬───────────────┘     └──┬──┘
                        Hash                    Version

h7zllwcidvkg8i5v6hkf49n3sd5lq290-openssl-3.0.5/
hggh523whplc4bk681c95r52bsjc2wb5-openssl-3.0.9/
ii5lq0igwk9xpq16s98yqswsgr1dbfi2-openssl-3.0.9/
ijk9j536zs30kha06rr966gplwxd7fbg-openssl-3.0.8/
ip9kk8kla5bff32mqjmwdn29sbhyd19c-openssl-3.0.8/
iw4cmla0978f1lgn23lmqmra3lrfwd4a-openssl-3.0.9/

{ pkgs ? import <nixpkgs> { }, ... }: {
  hello-rs = pkgs.rustPlatform.buildRustPackage {
    name = "hello-rs";
    src = ./.;
    cargoLock = { lockFile = ./Cargo.lock; };
  };
}

{引数}: 出力

nix-build

$ readlink ./result
/nix/store/hgaxjl9qvcla891yg6ipzphnl6sgj0hw-hello-rs

{ pkgs ? import <nixpkgs> { }, ... }:
let
  hello-rs = (import ./default.nix pkgs).hello-rs;
in
pkgs.mkShell {
  buildInputs = [
    hello-rs
  ];
}

bash-5.1# nix-shell
# パッケージのビルドが走る

[nix-shell:~/hello-rs]# hello-rs
Hello, world!

[nix-shell:~/hello-rs]# exit
exit

bash-5.1# hello
bash: hello: command not found

$ ls ~/.nix-profile
bin  etc  lib  libexec  manifest.nix  sbin  share

$ echo $PATH
/root/.nix-profile/bin:(中略)

$ which curl
/root/.nix-profile/bin/curl

$ readlink $(which curl)
/nix/store/52fbv6j49khca4cfvwm35fqd984w2520-curl-7.86.0-bin/bin/curl

$ readlink ~/.nix-profile
/nix/var/nix/profiles/default

$ readlink ~/.nix-profile
/nix/var/nix/profiles/default

$ ls -l /nix/var/nix/profiles/
default -> default-4-link
default-1-link -> /nix/store/d8c5588zaaylx31hax59j4pjj9pcik88-user-environment
default-2-link -> /nix/store/15nriql44lwh2dw9q5x8p22kaa882maz-profile
default-3-link -> /nix/store/hf0yc0syc71y9yryn9qqyhsq4i7kj0hi-profile
default-4-link -> /nix/store/15nriql44lwh2dw9q5x8p22kaa882maz-profile
per-user

{
  inputs = {
    # 依存するFlakeを指定
  };
  outputs = inputs: {
    # 任意のNix式をここに定義
  };
}

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs";
  };
  outputs = inputs: {};
}

outputs = inputs: {
  packages."<system>"."<name>" = derivation;
  devShells."<system>"."<name>" = derivation;
  # templates, apps, formatter, overlays, nixosModules, etc...
};

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs";
  };
  outputs = inputs:
  let
    pkgs = import inputs.nixpkgs {
      system = "x86_64-linux";
    };
  in
  {
    packages."x86_64-linux" = import ./default.nix pkgs;
  };
}

git add .
nix build .#hello-rs

nix build github:nixos/nixpkgs#git

{
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/master";

  outputs = inputs: let
    pkgs = import inputs.nixpkgs {
      system = "x86_64-linux";
    };
  in {
    devShells."x86_64-linux".default = pkgs.mkShell {
      buildInputs = with pkgs; [
        deno
      ];
    };
  };
}

echo "use flake" >> .envrc
direnv allow # direnv有効化

$ ls /nix/var/nix/profiles/system
activate  append-initrd-secrets  bin  boot.json  dry-activate  etc
extra-dependencies  firmware  init  init-interface-version  initrd
kernel  kernel-modules  kernel-params  nixos-version  specialisation
sw  system  systemd

{pkgs, ...}: {
  i18n.inputMethod = {
    enabled = "fcitx5";
    fcitx5.addons = [pkgs.fcitx5-mozc];
  };

  fonts = {
    fonts = with pkgs; [
      noto-fonts-cjk-serif
      noto-fonts-cjk-sans
      noto-fonts-emoji
      nerdfonts
    ];
    fontDir.enable = true;
    fontconfig = {
      defaultFonts = {
        serif = ["Noto Serif CJK JP" "Noto Color Emoji"];
        sansSerif = ["Noto Sans CJK JP" "Noto Color Emoji"];
        monospace = ["JetBrainsMono Nerd Font" "Noto Color Emoji"];
        emoji = ["Noto Color Emoji"];
      };
    };
  };
}

$ ls /etc/nixos/
configuration.nix hardware-configuration.nix

sudo nano /etc/nixos/configuration.nix

# Edit this configuration file to define what should be installed on
# your system.  Help is available in the configuration.nix(5) man page
# and in the NixOS manual (accessible by running ‘nixos-help’).

{ config, pkgs, ... }:

{
   # 各種設定...

+  nix = {
+    settings = {
+      experimental-features = ["nix-command" "flakes"];
+    };
+  };
}

sudo nixos-rebuild switch

nix run github:nixos/nixpkgs/nixpkgs-unstable#neofetch

nix run nixpkgs#neofetch

nix registry list

mkdir ~/.dotfiles && cd ~/.dotfiles
cp /etc/nixos/* .
git init

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs = inputs: {
    nixosConfigurations = {
      myNixOS = inputs.nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          ./configuration.nix
        ];
      };
    };
  };
}

sudo nixos-rebuild switch --flake .#myNixOS

{ config, pkgs, ... }:
{
  # 各種設定...

  users.users.ユーザー名 = {
    # ...
+    shell = pkgs.zsh; # デフォルトのシェルをZSHに変更
  };

  # ...

+  # 設定込みでパッケージを有効化
+  programs = {
+    git = {
+      enable = true;
+    };
+    neovim = {
+      enable = true;
+      defaultEditor = true; # $EDITOR=nvimに設定
+      viAlias = true;
+      vimAlias = true;
+    };
+    starship = {
+      enable = true;
+    };
+    zsh = {
+      enable = true;
+    };
+  };
}

{ config, pkgs, ... }:
{
  # 各種設定

+ i18n.inputMethod = {
+   enabled = "fcitx5";
+   fcitx5.addons = [pkgs.fcitx5-mozc];
+ };

+ fonts = {
+   fonts = with pkgs; [
+     noto-fonts-cjk-serif
+     noto-fonts-cjk-sans
+     noto-fonts-emoji
+     nerdfonts
+   ];
+   fontDir.enable = true;
+   fontconfig = {
+     defaultFonts = {
+       serif = ["Noto Serif CJK JP" "Noto Color Emoji"];
+       sansSerif = ["Noto Sans CJK JP" "Noto Color Emoji"];
+       monospace = ["JetBrainsMono Nerd Font" "Noto Color Emoji"];
+       emoji = ["Noto Color Emoji"];
+     };
+   };
+ };
}

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+   nixos-hardware.url = "github:NixOS/nixos-hardware/master"; # ハードウェア設定のコレクション
+   xremap.url = "github:xremap/nix-flake"; # キー設定をいい感じに変更できるツール
  };

  outputs = inputs: {
    nixosConfigurations = {
      myNixOS = inputs.nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          ./configuration.nix
        ];
+       specialArgs = {
+           inherit inputs; # `inputs = inputs;`と等しい
+       };
      };
    };
  };
}

{
+ inputs,
  config,
  pkgs,
  ...
}:
{
  imports =
    [
      # ...
    ]
+   # 環境に応じてインポートするモジュールを変更してください
+   ++ (with inputs.nixos-hardware.nixosModules; [
+     common-cpu-amd
+     common-gpu-nvidia
+     common-pc-ssd
+   ]);
+   # xremapのNixOS modulesを使えるようにする
+   ++ [
+     inputs.xremap.nixosModules.default
+   ]

+ # xremapでキー設定をいい感じに変更
+ services.xremap = {
+   userName = "ユーザー名";
+   serviceMode = "system";
+   config = {
+     modmap = [
+       {
+         # CapsLockをCtrlに置換
+         name = "CapsLock is dead";
+         remap = {
+           CapsLock = "Ctrl_L";
+         };
+       }
+     ];
+     keymap = [
+       {
+         # Ctrl + HがどのアプリケーションでもBackspaceになるように変更
+         name = "Ctrl+H should be enabled on all apps as BackSpace";
+         remap = {
+           C-h = "Backspace";
+         };
+         # 一部アプリケーション（ターミナルエミュレータ）を対象から除外
+         application = {
+           not = ["Alacritty" "Kitty" "Wezterm"];
+         };
+       }
+     ];
+   };
+ };
}

{ config, pkgs, ... }:
{
+ # カーネルを変更する
+ boot.kernelPackages = pkgs.linuxKernel.packages.linux_zen;

+ # ホスト名を変更する
+ networking.hostName = "好きなホスト名";

  nix = {
    settings = {
+     auto-optimise-store = true; # Nix storeの最適化
      experimental-features = ["nix-command" "flakes"];
    };
+   # ガベージコレクションを自動実行
+   gc = {
+     automatic = true;
+     dates = "weekly";
+     options = "--delete-older-than 7d";
+   };
  };

+ # プロプライエタリなパッケージを許可する
+ nixpkgs.config.allowUnfree = true;

+ # tailscale（VPN）を有効化
+ # 非常に便利なのでおすすめ
+ services.tailscale.enable = true;
+ networking.firewall = {
+   enable = true;
+   # tailscaleの仮想NICを信頼する
+   # `<Tailscaleのホスト名>:<ポート番号>`のアクセスが可能になる
+   trustedInterfaces = ["tailscale0"];
+   allowedUDPPorts = [config.services.tailscale.port];
+ };

+ # サウンド設定 - (デフォルトでこうなっているかもしれない)
+ sound.enable = true;
+ hardware.pulseaudio.enable = false; # pipewireに置き換える
+ security.rtkit.enable = true; # pipewireに必要
+ services.pipewire = {
+   enable = true;
+   alsa.enable = true;
+   alsa.support32Bit = true;
+   jack.enable = true;
+   pulse.enable = true;
+ };

+ # マイク用ノイズ低減アプリ
+ programs = {
+   noisetorch.enable = true;
+ };

+ # Dockerをrootlessで有効化
+ virtualisation = {
+   docker = {
+     enable = true;
+     rootless = {
+       enable = true;
+       setSocketVariable = true; # $DOCKER_HOSTを設定
+     };
+   };
+ };

+ # Linuxデスクトップ向けのパッケージマネージャ
+ # アプリケーションをサンドボックス化して実行する
+ # NixOSが対応していないアプリのインストールに使う
+ services.flatpak.enable = true;
+ xdg.portal.enable = true; # flatpakに必要

+ # Steamをインストール
+ # Proton ExperimentalはSteamの設定から有効化する
+ programs.steam = {
+   enable = true;
+   remotePlay.openFirewall = true;
+   dedicatedServer.openFirewall = true;
+ };

+ # Steamのフォントが文字化けするので、フォント設定を追加
+ # SteamだけフォントをMigu 1Pにする
  fonts = {
    fonts = with pkgs; [
      # ...
+     migu
    ];
    fontDir.enable = true;
    fontconfig = {
      # ...
+     localConf = ''
+       <?xml version="1.0"?>
+       <!DOCTYPE fontconfig SYSTEM "urn:fontconfig:fonts.dtd">
+       <fontconfig>
+         <description>Change default fonts for Steam client</description>
+         <match>
+           <test name="prgname">
+             <string>steamwebhelper</string>
+           </test>
+           <test name="family" qual="any">
+             <string>sans-serif</string>
+           </test>
+           <edit mode="prepend" name="family">
+             <string>Migu 1P</string>
+           </edit>
+         </match>
+       </fontconfig>
+     '';
    };
  };
}

{
  inputs = {
    # ...
+   home-manager = {
+     url = "github:nix-community/home-manager";
+     inputs.nixpkgs.follows = "nixpkgs";
+   };
  };

  outputs = inputs: {
    # ...
+   homeConfigurations = {
+     myHome = inputs.home-manager.lib.homeManagerConfiguration {
+       pkgs = import inputs.nixpkgs {
+         system = "x86_64-linux";
+         config.allowUnfree = true; # プロプライエタリなパッケージを許可
+       };
+       extraSpecialArgs = {
+         inherit inputs;
+       };
+       modules = [
+         ./home.nix
+       ];
+     };
+   };
}

{
  home = rec { # recでAttribute Set内で他の値を参照できるようにする
    username="ユーザー名";
    homeDirectory = "/home/${username}"; # 文字列に値を埋め込む
    stateVersion = "22.11";
  };
  programs.home-manager.enable = true; # home-manager自身でhome-managerを有効化
}

rm flake.lock
git add .
nix run nixpkgs#home-manager -- switch --flake .#myHome

home.file = {
  "wallpaper.png" = {
    target = "Wallpaper/wallpaper.png"; # ~/Wallpaper/wallpaper.pngに配置
    source = ./wallpaper.png; # 配置するファイル
  };
};

+ home.packages = with pkgs; [
+   bat
+   bottom
+   exa
+   httpie
+   pingu
+   ripgrep
+ ];

home.packages = [
  pkgs.bat
  pkgs.bottom
  pkgs.eza
  pkgs.httpie
  pkgs.pingu
  pkgs.ripgrep
];

{pkgs, ...}: {
  programs.zsh = {
    enable = true;
    autocd = true; # cdなしでファイルパスだけで移動
    enableCompletion = true; # 自動補完
    enableAutosuggestions = true; # 入力サジェスト
    syntaxHighlighting.enable = true; # シンタックスハイライト
    shellAliases = {
      cat = "bat";
      grep = "rg";
      ls = "eza --icons always --classify always";
      la = "eza --icons always --classify always --all ";
      ll = "eza --icons always --long --all --git ";
      tree = "eza --icons always --classify always --tree";
    };
  };
}

{pkgs, ...}: {
  programs.git = {
    enable = true;
    userName = "Git用のユーザー名";
    userEmail = "Git用のメールアドレス";
  };

  # GitHub CLI
  programs.gh = {
    enable = true;
    extensions = with pkgs; [gh-markdown-preview]; # オススメ
    settings = {
      editor = "nvim";
    };
  };
}

{pkgs, ...}: {
  programs.neovim = {
    enable = true;
    viAlias = true;
    vimAlias = true;
    plugins = with pkgs.vimPlugins; [
      # Treesitter
      (nvim-treesitter.withPlugins (plugins:
        with plugins; [
          tree-sitter-markdown
          tree-sitter-nix
          # ...
        ]))
      telescope-nvim
      # ...
    ];

    # Neovim内部でのみPATHが通されるパッケージ
    # LSPやフォーマッタ、その他Neovimから呼び出すツールを指定しよう
    extraPackages = with pkgs; [
      ripgrep
      biome
      nodePackages.eslint
      nodePackages.prettier
      nodePackages.typescript-language-server
      # ...
    ];

    # ~/.config/nvim/init.luaに文字列が展開される
    extraLuaConfig = builtins.readFile ./init.lua;
  };
}

{
  programs.direnv = {
    enable = true;
    nix-direnv.enable = true;
  };
}

{pkgs, ...}: {
  home.packages = with pkgs; [
    gcc
    go
    nodejs-slim # npmのないNode.js単体
    nodePackages.pnpm
    nodePackages.wrangler
    deno
    bun
    python312
    zig
  ];
}

{
  inputs = {
    # ...
+   rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = inputs: {
    # ...
    homeConfigurations = {
      myHome = inputs.home-manager.lib.homeManagerConfiguration {
        pkgs = import inputs.nixpkgs {
          system = "x86_64-linux";
          config.allowUnfree = true; # プロプライエタリなパッケージを許可
+         overlays = [(import inputs.rust-overlay)];
        };
        extraSpecialArgs = {
          inherit inputs;
        };
        modules = [
          ./home.nix
        ];
      };
    };
}

{pkgs, ...}: {
  home.packages = with pkgs; [
    # ...
+   rust-bin.stable.latest.default
  ];
}

- rust-bin.stable.latest.default
+ (rust-bin.stable.latest.default.override {
+   targets = ["wasm32-unknown-unknown" "wasm32-wasi"];
+ })

{
  programs.wezterm = {
    enable = true;
    extraConfig = builtins.readFile ./wezterm.lua;
  };
}

local wezterm = require("wezterm")

return {
	-- Theme
	color_scheme = "MyTheme",

	-- Font
	font = wezterm.font_with_fallback({
		{ family = "JetBrainsMono Nerd Font", weight = "Regular" },
		{ family = "JetBrainsMono Nerd Font", weight = "Regular", assume_emoji_presentation = true },
		{ family = "Noto Sans CJK JP" },
	}),
	font_size = 14.0,

	-- Padding
	window_padding = {
		left = 10,
		right = 10,
		top = 10,
		bottom = 10,
	},

	-- Tab
	use_fancy_tab_bar = false,
	hide_tab_bar_if_only_one_tab = true,

	-- Misc
	use_ime = true, -- Enable IME
	check_for_updates = false, -- Disable update check
	audible_bell = "Disabled", -- Disable bell
}

{
  programs = {
    firefox.enable = true;
    google-chrome.enable = true;
    vivaldi = {
      enable = true;
      commandLineArgs = ["--enable-features=WebUIDarkMode" "--force-dark-mode"];
    };
  };
}

{pkgs, ...}: {
  # Spotify TUI
  programs.ncspot.enable = true;

  # OBS
  programs.obs-studio.enable = true;

  home.packages = with pkgs; [
    discord
    discord-ptb
    gnome.totem # ビデオプレーヤー
    gnome.evince # PDFビューアー
    parsec-bin # 超速いリモートデスクトップクライアント
    remmina # VNCクライアント
    slack
    spotify
  ];
}

{
  imports = [
    ./zsh.nix
    ./starship.nix
    ./neovim.nix
    ./direnv.nix
    ./development.nix
    ./wezterm.nix
    ./browser.nix
    ./apps.nix
  ];

  # ...
}